Add bomb-only mode

LTTP_RND_GeneralBugfixes.asm

@@ -58,6 +58,7 @@ db #$20, #$19, #$08, #$31 ; year/month/day
 ;$7EF420 - $7EF466 - Stat Tracking Bank 1 (overlaps with RNG Item Flags)
 ;$7EF450 - $7EF45F - RNG Item (Single) Flags
 ;$7EF4A0 - $7EF4A7 - Service Request Block
+!PROGRESSIVE_BOMBS = "$7EF4A8"
 !FRESH_FILE_MARKER = "$7EF4F0" ; zero if fresh file
 ;$700500 - $70050F - Extended File Name
 ;$701000 - $70100F - Password (incorporate into log header)
@@ -221,6 +222,7 @@ incsrc fastcredits.asm
 incsrc msu.asm
 incsrc multiworld.asm
 incsrc terrorpin.asm
+incsrc special_bombs.asm
 warnpc $A58000
 
 ;org $228000 ; contrib area
@@ -300,6 +302,11 @@ InvertedCastleHole: ;address used by front end. DO NOT MOVE!
 incbin sheet73.gfx
 warnpc $31E501
 
+org $31E800
+Damage_Table_Alt:
+incbin damage_table_sword_bombs.bin
+warnpc $31F001
+
 org $338000
 GFX_HUD_Palette:
 incbin hudpalette.pal

darkworldspawn.asm

@@ -142,9 +142,10 @@ SetEscapeAssist:
 		BIT.b #$01 : BEQ + : STA !INFINITE_ARROWS : +
 		BRA ++
 	.no_train ; choo choo
-		LDA.l EscapeAssist : BIT.b #$04 : BEQ + : LDA.b #$00 : STA !INFINITE_MAGIC : +
+		LDA.l EscapeAssist
-		LDA.l EscapeAssist : BIT.b #$02 : BEQ + : LDA.b #$00 : STA !INFINITE_BOMBS : +
+		BIT.b #$40 : BEQ + : STA !INFINITE_MAGIC : +
-		LDA.l EscapeAssist : BIT.b #$01 : BEQ + : LDA.b #$00 : STA !INFINITE_ARROWS : +
+		BIT.b #$20 : BEQ + : STA !INFINITE_BOMBS : +
+		BIT.b #$10 : BEQ + : STA !INFINITE_ARROWS : +
 	++
 RTL
 ;--------------------------------------------------------------------------------

dialog.asm

@@ -304,6 +304,10 @@ DialogGanon2:
 	REP #$20
 	BCS +
 		LDA.w #$018D : BRA ++
+	+
+		LDA.l SpecialBombs
+		AND.w #$00FF : BEQ + ; branch if not special bomb mode
+		LDA.w #$0195 : BRA ++
 	+
 		LDA.l $7EF38E
 

generate_bomb_table.rb

@@ -0,0 +1,64 @@
+def process_values(sprite, values)
+  ret = values.clone
+  if [1, 2].include?(ret[0]) # boomerang
+    ret[0] = 0
+  end
+  if ret[6] > 0 && sprite != 0x84 # bow and not red eyegore/mimic
+    ret[6] = 0
+  end
+  if ret[7] == 2 # hookshot
+    ret[7] = 0
+  end
+  if ret[9] > 0 && sprite != 0x84 # silver bow and not red eyegore/mimic
+    ret[9] = 0
+  end
+  if ret[10] == 4 # powder
+    ret[10] = 0
+  end
+  if ret[11] > 0 && ![0xA1, 0xA3, 0xCD].include?(sprite) # fire rod
+    ret[11] = 0
+  end
+  if ret[12] != 3 && sprite != 0xCC # ice rod
+    ret[12] = 0
+  end
+  if ret[13] != 3 && ![0xA3, 0xA1].include?(sprite) # bombos
+    ret[13] = 0
+  end
+  if ret[14] != 1 # ether
+    ret[14] = 0
+  end
+  if ret[15] != 3 # quake
+    ret[15] = 0
+  end
+  return ret
+end
+
+def split_value(byte)
+  return [byte >> 4, byte & 0x0F]
+end
+
+def join_values(value1, value2)
+  return (value1 & 0x0F) << 4 | (value2 & 0x0F)
+end
+
+File.open("damage_table.bin") do |input|
+  File.open("damage_table_sword_bombs.bin", "w") do |output|
+    i_enum = input.each_byte
+    (0...0xD7).each do |sprite|
+      values = []
+      (0...8).each do
+        values += split_value(i_enum.next)
+      end
+      v_enum = process_values(sprite, values).to_enum
+      (0...8).each do
+        output.putc(join_values(v_enum.next, v_enum.next))
+      end
+    end
+    begin
+      while true
+        output.putc(i_enum.next)
+      end
+    rescue StopIteration
+    end
+  end
+end

hooks.asm

@@ -326,6 +326,12 @@ JSL.l LoadBombCount16
 org $0DDEB3 ; <- 6DEB3 - equipment.asm : 328 (LDA $7EF33F, X)
 JSL.l IsItemAvailable
 ;--------------------------------------------------------------------------------
+org $0DDDE8 ; <- 6DDE8 - equipment.asm : 148 (LDA $7EF340)
+JSL.l SearchForEquippedItem
+;--------------------------------------------------------------------------------
+org $0DDE70 ; <- 6DE70 - equipment.asm : 273 (LDA $7EF340)
+JSL.l SearchForEquippedItem
+;--------------------------------------------------------------------------------
 org $0DE39D ; <- 6E39D - equipment.asm : 1109 (LDA $7EF340)
 JSL.l SearchForEquippedItem
 ;--------------------------------------------------------------------------------
@@ -922,12 +928,9 @@ LDA.w AddReceivedItemExpanded_item_target_addr+1, X
 org $09861F ; 4861F - ancilla_init.asm:724 (LDA .item_values, Y)
 LDA.w AddReceivedItemExpanded_item_values, Y
 
-org $098627 ; 48627 - ancilla_init.asm:731 (LDA .item_target_addr+0, X)
+org $098624 ; 48624 - ancilla_init.asm:728 (TYA : ASL A : TAX)
-LDA.w AddReceivedItemExpanded_item_target_addr+0, X
+JSL.l UpdateInventoryLocationExpanded
-org $09862C ; 4862C - ancilla_init.asm:722 (LDA .item_target_addr+1, X)
+BRA + : NOP #18 : +
-LDA.w AddReceivedItemExpanded_item_target_addr+1, X
-org $098635 ; 48635 - ancilla_init.asm:727 (LDA .item_values, Y)
-LDA.w AddReceivedItemExpanded_item_values, Y
 
 org $0986AA ; 486AA - ancilla_init.asm:848 (LDA .item_masks, X)
 LDA.w AddReceivedItemExpanded_item_masks, X
@@ -2335,9 +2338,6 @@ NOP #6
 ;--------------------------------------------------------------------------------
 org $09865E ; <- 4865E
 JSL.l $1BEE1B ; fix something i wrote over i shouldn't have
-;--------------------------------------------------------------------------------
-org $098638 ; <- 48638 - ancilla_init.asm:737 - LDA .item_values, Y : BMI .dontWrite (BMI)
-JSL.l ItemDowngradeFix
 ;================================================================================
 
 ;================================================================================
@@ -2719,3 +2719,44 @@ JSL FixTerrorpin ; 4 bytes
 NOP				 ; 1 byte
 ;--------------------------------------------------------------------------------
 
+;================================================================================
+; Bomb-Only Mode
+;--------------------------------------------------------------------------------
+org $06ECC3 ; Bank06.asm@4704 (PHX : TAX : LDA.l .damage_classes, X : PLX)
+JSL DamageClassCalc
+BRA + : NOP #29 : +
+;--------------------------------------------------------------------------------
+org $0882D4 ; Bank08.asm@445 (PHX : TYX : ... )
+JSL Utility_CheckAncillaOverlapWithSprite
+BRA + : NOP #5 : +
+;--------------------------------------------------------------------------------
+org $088DB1 ; Bank08.asm@1207 (PHY : PHX : TYX : ... )
+JSL Utility_CheckAncillaOverlapWithSprite
+BRA + : NOP #7 : +
+--------------------------------------------------------------------------------
+org $0882E8 ; Bank08.asm@456 (LDA $0DB0, Y : CMP.b #$03)
+JSL Utility_CheckHelmasaurKingCollision
+NOP
+;--------------------------------------------------------------------------------
+org $1E838C ; sprite_helmasaur_king.asm@522 (LDA $0301 : AND.b #$0A)
+JSL Utility_CheckHammerHelmasaurKingMask
+NOP
+;--------------------------------------------------------------------------------
+org $06ED94 ; Bank06.asm@4866 (LDA $0E60, X : AND.b #$40)
+JSL Utility_CheckImpervious
+NOP
+;--------------------------------------------------------------------------------
+org $068F94 ; sprite_prep.asm@1984 (INC $0BA0, X : JSL Sprite_InitializedSegmented)
+JSL AllowBombingMoldorm
+BRA + : NOP : +
+;--------------------------------------------------------------------------------
+org $0DEE05 ; equipment.asm@2065 (LDA $7EF359 : AND.w #$00FF : CMP.w #$00FF : ...)
+JSL DrawSwordInMenu
+BRA + : NOP #16 : +
+;--------------------------------------------------------------------------------
+org $0DFC51 ; is this being used? I hope not! let's find out if anything breaks!
+db $B2, $3C, $B3, $3C, $C2, $3C, $17, $3C
+db $B2, $2C, $B3, $2C, $C2, $2C, $18, $2C
+db $B2, $24, $B3, $24, $C2, $24, $19, $24
+db $B2, $28, $B3, $28, $C2, $28, $1A, $28
+db $B2, $28, $B3, $28, $C2, $28, $1B, $28

newitems.asm

@@ -40,6 +40,11 @@
 ; #$90 - Big Keys
 ; #$A0 - Small Keys
 ; #$B0 - Bee Trap
+; #$B1 - L-2 Bombs
+; #$B2 - L-3 Bombs
+; #$B3 - L-4 Bombs
+; #$B4 - L-5 Bombs
+; #$B5 - Progressive Bombs
 ; #$FE - Server Request (Asychronous Chest)
 ; #$FF - Null Chest
 ;--------------------------------------------------------------------------------
@@ -276,7 +281,7 @@ AddReceivedItemExpandedGetItem:
 	+ CMP.b #$57 : BNE + ; Programmable Object 3
 		%ProgrammableItemLogic(3)
 		JMP .done
-	+ CMP.b #$58 : BNE + ; Upgrade-Only Sivler Arrows
+	+ CMP.b #$58 : BNE + ; Upgrade-Only Silver Arrows
 		LDA.l SilverArrowsUseRestriction : BNE +++
 		LDA.l SilverArrowsAutoEquip : AND.b #$01 : BEQ +++
 			LDA $7EF340 : BEQ ++ : CMP.b #$03 : !BGE ++
@@ -412,6 +417,7 @@ AddReceivedItemExpandedGetItem:
 	PLX
 	LDA $02E9 : CMP.b #$01 ; thing we wrote over
 RTL
+;--------------------------------------------------------------------------------
 ; #$70 - Maps
 ; #$80 - Compasses
 ; #$90 - Big Keys
@@ -529,9 +535,9 @@ AddReceivedItemExpanded:
 			LDA $7EF340 : INC : LSR : CMP.l ProgressiveBowLimit : !BLT +
 				LDA.l ProgressiveBowReplacement : STA $02D8 : JMP .done
 			+ LDA $7EF340 : INC : LSR : CMP.b #$00 : BNE + ; No Bow
-				LDA.b #$3A : STA $02D8 : BRA .done
+				LDA.b #$3A : STA $02D8 : JMP .done
 			+ ; Any Bow
-				LDA.b #$3B : STA $02D8 : BRA .done
+				LDA.b #$3B : STA $02D8 : JMP .done
 		++ : CMP.b #$65 : BNE ++ ; Progressive Bow 2
 			LDA !MULTIWORLD_ITEM_PLAYER_ID : BNE +++
 				LDA.l !INVENTORY_SWAP_2 : ORA #$20 : STA.l !INVENTORY_SWAP_2
@@ -552,6 +558,16 @@ AddReceivedItemExpanded:
 			LDA !MULTIWORLD_ITEM_PLAYER_ID : BEQ +++
 				LDA.b #$0E : STA $02D8 : BRA .done ; Bee in a bottle
 			+++
+		++ : CMP.b #$B5 : BNE ++ ; Progressive Bombs
+			LDA $7EF4A8
+			CMP.b #$00 : BNE + ; L-1 Bombs
+				LDA.b #$B1 : STA $02D8 : JMP .done
+			+ : CMP.b #$01 : BNE + ; L-2 Bombs
+				LDA.b #$B2 : STA $02D8 : JMP .done
+			+ : CMP.b #$02 : BNE + ; L-3 Bombs
+				LDA.b #$B3 : STA $02D8 : JMP .done
+			+ ; Everything Else
+				LDA.b #$B4 : STA $02D8 : JMP .done
 		++
 		.done
 	PLX : PLA
@@ -563,6 +579,7 @@ AddReceivedItemExpanded:
 ;DATA AddReceivedItemExpanded
 {
 ; This is a temporary measure for Fish to have consistent addresses
+warnpc $A08800
 org $A08800
 
 .y_offsets
@@ -585,7 +602,7 @@ org $A08800
 	db -5 ; Master Sword (Safe)
 	db -4, -4, -4, -4 ; +5/+10 Bomb Arrows
 	db -4, -4, -4 ; 3x Programmable Item
-	db -4 ; Upgrade-Only Sivler Arrows
+	db -4 ; Upgrade-Only Silver Arrows
 	db -4 ; 1 Rupoor
 	db -4 ; Null Item
 	db -4, -4, -4 ; Red, Blue & Green Clocks
@@ -600,7 +617,8 @@ org $A08800
 	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Free Big Key
 	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Free Small Key
 	db -4 ; Bee Trap
-	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Unused
+	db -4, -4, -4, -4, -4 ; Bomb Upgrades
+	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Unused
 	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Unused
 	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Unused
 	db -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4, -4 ; Unused
@@ -625,7 +643,7 @@ org $A08800
 	db  4 ; Master Sword (Safe)
 	db  0,  0,  0,  0 ; +5/+10 Bomb Arrows
 	db  0,  0,  0 ; 3x Programmable Item
-	db  0 ; Upgrade-Only Sivler Arrows
+	db  0 ; Upgrade-Only Silver Arrows
 	db  4 ; 1 Rupoor
 	db  0 ; Null Item
 	db  0, 0, 0 ; Red, Blue & Green Clocks
@@ -641,7 +659,8 @@ org $A08800
 	;db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; *EVENT*
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Free Small Key
 	db  0 ; Bee Trap
-	db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; Unused
+	db  0, 0, 0, 0, 0 ; Bomb Upgrades
+	db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; Unused
 	db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; Unused
 	db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; Unused
 	db  0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ; Unused
@@ -667,7 +686,7 @@ org $A08800
 	db $18 ; Master Sword (Safe)
 	db $3D, $3E, $3F, $40 ; +5/+10 Bomb Arrows
 	db $00, $00, $00 ; 3x Programmable Item
-	db $41 ; Upgrade-Only Sivler Arrows
+	db $41 ; Upgrade-Only Silver Arrows
 	db $24 ; 1 Rupoor
 	db $47 ; Null Item
 	db $48, $48, $48 ; Red, Blue & Green Clocks
@@ -687,7 +706,8 @@ org $A08800
 	;db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; *EVENT*
 
 	db $47 ; Bee Trap
-	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
+	db $13, $13, $13, $13, $13 ; Bomb Upgrades
+	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
@@ -712,7 +732,7 @@ org $A08800
 	db $00 ; Master Sword (Safe)
 	db $02, $02, $02, $02 ; +5/+10 Bomb Arrows
 	db $02, $02, $02 ; 3x Programmable Item
-	db $02 ; Upgrade-Only Sivler Arrows
+	db $02 ; Upgrade-Only Silver Arrows
 	db $00 ; 1 Rupoor
 	db $02 ; Null Item
 	db $02, $02, $02 ; Red, Blue & Green Clocks
@@ -727,8 +747,8 @@ org $A08800
 	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Free Big Key
 	db $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00, $00 ; Free Small Key
 	db $02 ; Bee Trap
-
+	db $02, $02, $02, $02, $02 ; Bomb Upgrades
-	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Unused
+	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Unused
 	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Unused
 	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Unused
 	db $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02, $02 ; Unused
@@ -754,7 +774,7 @@ org $A08800
 	db  5 ; Master Sword (Safe)
 	db  4,  4,  4,  4 ; +5/+10 Bomb Arrows
 	db  4,  4,  4 ; 3x Programmable Item
-	db  1 ; Upgrade-Only Sivler Arrows
+	db  1 ; Upgrade-Only Silver Arrows
 	db  3 ; 1 Rupoor
 	db  1 ; Null Item
 	db  1, 2, 4 ; Red, Blue & Green Clocks
@@ -769,7 +789,8 @@ org $A08800
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Free Big Key
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Free Small Key
 	db  1 ; Bee Trap
-	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Unused
+	db  5, 5, 5, 5, 5 ; Bomb Upgrades
+	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Unused
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Unused
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Unused
 	db  4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4, 4 ; Unused
@@ -796,7 +817,7 @@ org $A08800
 	dw $F359 ; Master Sword (Safe)
 	dw $F375, $F375, $F376, $F376 ; +5/+10 Bomb Arrows
 	dw $F41A, $F41C, $F41E ; 3x Programmable Item
-	dw $F340 ; Upgrade-Only Sivler Arrows
+	dw $F340 ; Upgrade-Only Silver Arrows
 	dw $F360 ; 1 Rupoor
 	dw $F36A ; Null Item
 	dw $F454, $F454, $F454 ; Red, Blue & Green Clocks
@@ -811,7 +832,8 @@ org $A08800
 	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Free Big Key
 	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Free Small Key
 	dw $F36A ; Bee Trap
-	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Unused
+	dw $F4A8, $F4A8, $F4A8, $F4A8, $F4A8 ; Bomb Upgrades
+	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Unused
 	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Unused
 	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Unused
 	dw $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A, $F36A ; Unused
@@ -840,7 +862,7 @@ org $A08800
 	db $02 ; Master Sword (Safe)
 	db $FF, $FF, $FF, $FF ; +5/+10 Bomb Arrows
 	db $FF, $FF, $FF ; 3x Programmable Item
-	db $FF ; Upgrade-Only Sivler Arrows
+	db $FF ; Upgrade-Only Silver Arrows
 	db $FF ; 1 Rupoor
 	db $FF ; Null Item
 	db $FF, $FF, $FF ; Red, Blue & Green Clocks
@@ -855,7 +877,8 @@ org $A08800
 	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Free Big Key
 	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Free Small Key
 	db $FF ; Bee Trap
-	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Unused
+	db $01, $02, $03, $04, $FF ; Bomb Upgrades
+	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Unused
 	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Unused
 	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Unused
 	db $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF, $FF ; Unused
@@ -942,7 +965,8 @@ Link_ReceiveItemAlternatesExpanded:
 	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Free Big Key
 	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Free Small Key
 	db -1 ; Bee Trap
-	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Unused
+	db -1, -1, -1, -1, -1 ; Bomb Upgrades
+	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Unused
 	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Unused
 	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Unused
 	db -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1, -1 ; Unused
@@ -1178,3 +1202,19 @@ ChestPrep:
 	SEC
 RTL
 ;--------------------------------------------------------------------------------
+UpdateInventoryLocationExpanded:
+{
+	REP #$30
+	TYA : AND #$00FF : ASL A : TAX
+
+	; Tells what inventory location to write to.
+	LDA.w AddReceivedItemExpanded_item_target_addr, X : STA $00
+
+	SEP #$30
+
+	LDA.b #$7E : STA $02
+
+	LDA.w AddReceivedItemExpanded_item_values, Y
+	JSL ItemDowngradeFix
+	RTL
+}

special_bombs.asm

@@ -0,0 +1,246 @@
+;--------------------------------------------------------------------------------
+!ANCILLA_DAMAGE = "$06EC84"
+!BOMB_LEVEL = "$7EF4A8"
+; start with X = sprite index, A = ancilla index
+;--------------------------------------------------------------------------------
+DamageClassCalc:
+	CMP #$01 : BEQ .cane
+	CMP #$2C : BEQ .cane
+	CMP #$31 : BEQ .cane
+	BRA .not_cane
+.cane
+	PHA
+	LDA SpecialBombs : BEQ .normal_cane
+	LDA $0E20, X : CMP.b #$1E : BEQ .normal_cane ; crystal switch
+	PLA
+.impervious
+	LDA #$FF
+	RTL
+.normal_cane
+	PLA
+.not_cane
+	CMP #$07 : BNE .no_change
+	LDA SpecialBombs : BEQ .normal_bombs
+	LDA $0E20, X : CMP.b #$D6 : BEQ .unstunned_ganon
+	CMP.b #$D7 : BEQ .stunned_ganon
+	CMP.b #$88 : BEQ .mothula
+	CMP.b #$92 : BEQ .helmasaur_king
+.bomb_level
+	LDA !BOMB_LEVEL : INC A
+	BRA .done
+.mothula
+	LDA !BOMB_LEVEL : INC A
+	CMP #$04 : !BGE .fix_mothula
+	BRA .done
+.fix_mothula
+	LDA #$03
+	BRA .done
+.helmasaur_king
+	LDA $0DB0, X : CMP #$03 : !BGE .bomb_level
+	LDA #$08
+	BRA .done
+.unstunned_ganon
+	LDA $04C5 : CMP.b #$02 : BNE .impervious
+	LDA $0EE0, X : BNE .impervious
+	LDA #$34 : STA $0EE0, X ; give the poor pig some iframes
+	BRA .bomb_level
+.stunned_ganon
+	LDA $0EE0, X : BNE .impervious
+	LDA #$34 : STA $0EE0, X ; give the poor pig some iframes
+	LDA #$20 : STA $0F10, X ; knock ganon back or something? idk
+	LDA #$09
+	BRA .done
+.normal_bombs
+	LDA #$07
+.no_change
+	PHX : TAX
+	LDA.l !ANCILLA_DAMAGE, X
+	PLX
+	CMP.b #$06 : BNE .done ; not arrows
+	LDA $7EF340 : CMP.b #$03 : !BGE .actual_silver_arrows
+	LDA #$06
+.done
+	RTL
+.actual_silver_arrows
+	LDA $0E20, X : CMP.b #$D7 : BNE +
+	LDA #$20 : STA $0F10, X
+	+
+	LDA #$09
+	RTL
+; end with X = sprite index, A = damage class
+;--------------------------------------------------------------------------------
+!SPRITE_SETUP_HIT_BOX_LONG = "$0683EA"
+!UTILITY_CHECK_IF_HIT_BOXES_OVERLAP_LONG = "$0683E6"
+; start with X = ancilla index, Y = sprite index
+;--------------------------------------------------------------------------------
+Utility_CheckAncillaOverlapWithSprite:
+	LDA $0E20, Y : CMP #$09 : BEQ .giant_moldorm
+	CMP #$CB : BEQ .trinexx
+.not_giant_moldorm ; ordinary collision checking
+	PHY : PHX
+	TYX
+	JSL !SPRITE_SETUP_HIT_BOX_LONG
+	PLX : PLY
+	JSL !UTILITY_CHECK_IF_HIT_BOXES_OVERLAP_LONG
+	RTL
+.ignore_collision
+	CLC
+	RTL
+.giant_moldorm
+	LDA $0C4A, X : CMP #$07 : BNE .ignore_collision ; don't collide with non-bombs
+	LDA.l SpecialBombs : BEQ .ignore_collision
+	LDA $0E10, Y : BNE .ignore_collision ; Moldy can have little a I-Frames, as a treat
+
+	JSR SetUpMoldormHitbox
+	JSL !UTILITY_CHECK_IF_HIT_BOXES_OVERLAP_LONG
+	RTL
+.trinexx
+	LDA $0C4A, X : CMP #$07 : BNE .ignore_collision ; don't collide with non-bombs
+	LDA.l SpecialBombs : BEQ .ignore_collision
+
+	JSR SetUpTrinexxHitbox
+	JSL !UTILITY_CHECK_IF_HIT_BOXES_OVERLAP_LONG
+	RTL
+; returns carry clear if there was no overlap
+;--------------------------------------------------------------------------------
+SetUpTrinexxHitbox:
+	; rearrange trinexx's hitbox to be her middle instead of her head
+	LDA $0CAA, Y : PHA
+	LDA $0E60, Y : PHA
+	LDA $0D10, Y : PHA
+	LDA $0D30, Y : PHA
+	LDA $0D00, Y : PHA
+	LDA $0D20, Y : PHA
+
+	LDA #$80 : STA $0CAA, Y
+
+	PHX
+	LDA $0E80, Y : !SUB.l $1DAF28 : AND.b #$7F : TAX
+
+	LDA $7FFC00, X : STA $0D10, Y
+	LDA $7FFC80, X : STA $0D30, Y
+	LDA $7FFD00, X : STA $0D00, Y
+	LDA $7FFD80, X : STA $0D20, Y
+
+	TYX
+	STZ $0E60, X
+
+	JSL !SPRITE_SETUP_HIT_BOX_LONG
+	PLX
+
+	PLA : STA $0D20, Y
+	PLA : STA $0D00, Y
+	PLA : STA $0D30, Y
+	PLA : STA $0D10, Y
+	PLA : STA $0E60, Y
+	PLA : STA $0CAA, Y
+	RTS
+;--------------------------------------------------------------------------------
+SetUpMoldormHitbox:
+	; rearrange moldorm's hitbox to be his tail instead of his head
+	LDA $0D90, Y : PHA
+	LDA $0F60, Y : PHA
+	LDA $0D10, Y : PHA
+	LDA $0D30, Y : PHA
+	LDA $0D00, Y : PHA
+	LDA $0D20, Y : PHA
+
+	PHY : PHX
+	LDA $0E80, Y : !SUB.b #$30 : AND.b #$7F : TAX
+
+	LDA $7FFC00, X : STA $0D10, Y
+	LDA $7FFC80, X : STA $0D30, Y
+	LDA $7FFD00, X : STA $0D00, Y
+	LDA $7FFD80, X : STA $0D20, Y
+	LDA #$01 : STA $09D0, Y
+
+	TYX
+	STZ $0F60, X
+
+	JSL !SPRITE_SETUP_HIT_BOX_LONG
+
+	PLX : PLY
+
+	PLA : STA $0D20, Y
+	PLA : STA $0D00, Y
+	PLA : STA $0D30, Y
+	PLA : STA $0D10, Y
+	PLA : STA $0F60, Y
+	PLA : STA $0D90, Y
+	RTS
+;--------------------------------------------------------------------------------
+; start with X = ancilla index, Y = sprite index
+Utility_CheckHelmasaurKingCollision:
+	LDA $0C4A, X : CMP #$07 : BNE .normal ; normal behavior with non-bombs
+	LDA.l SpecialBombs : BEQ .normal
+	CLC
+	RTL
+.normal
+	LDA $0DB0, Y : CMP.b #$03
+	RTL
+; returns carry set if there is collision immunity
+;--------------------------------------------------------------------------------
+Utility_CheckHammerHelmasaurKingMask:
+	LDA.l SpecialBombs : BNE .no_effect
+	LDA $0301 : AND #$0A
+	RTL
+.no_effect
+	LDA #$00
+	RTL
+;--------------------------------------------------------------------------------
+Utility_CheckImpervious:
+	LDA $0E20, X : CMP.b #$CB : BEQ .trinexx
+.normal
+	LDA $0E60, X : AND.b #$40 : BNE .impervious
+	LDA $0CF2 : CMP #$FF : BEQ .impervious ; special "always-impervious" class
+	LDA $0E20, X : CMP.b #$CC : BEQ .sidenexx : CMP.b #$CD : BEQ .sidenexx
+	LDA $0301 : AND.b #$0A : BEQ .not_impervious ; normal behavior if not hammer
+	LDA.l SpecialBombs : BEQ .not_impervious
+	LDA $0E20, X : CMP.b #$1E : BEQ .not_impervious ; crystal switch
+	CMP.b #$40 : BEQ .not_impervious ; aga barrier
+	BRA .impervious
+.trinexx
+	LDA SpecialBombs : BEQ .normal
+	LDA $0301 : AND.b #$0A : BNE .impervious ; impervious to hammer
+	BRA .not_impervious
+.sidenexx
+	LDA $0CAA, X : AND.b #$04 : BEQ .vulnerable
+	LDA SpecialBombs : BEQ .not_impervious
+	LDA $0CF2 : CMP #$06 : !BLT .impervious ; swords are ineffective
+	BRA .not_impervious
+.vulnerable
+	LDA SpecialBombs : BEQ .not_impervious
+	LDA $0CF2 : CMP #$06 : !BGE .impervious ; non-swords are ineffective
+	BRA .not_impervious
+.not_impervious
+	LDA #$00 : RTL
+.impervious
+	LDA #$01 : RTL
+; returns nonzero A if impervious
+;--------------------------------------------------------------------------------
+!SPRITE_INITIALIZED_SEGMENTED = "$1DD6D1"
+; start with X = sprite index
+;--------------------------------------------------------------------------------
+AllowBombingMoldorm:
+	LDA SpecialBombs : BNE .no_disable_projectiles
+	INC $0BA0, X
+.no_disable_projectiles
+	JSL !SPRITE_INITIALIZED_SEGMENTED
+	RTL
+;--------------------------------------------------------------------------------
+DrawSwordInMenu:
+	LDA $7EF359 : AND.w #$00FF : CMP.w #$00FF : BEQ .noSword
+.hasSword
+	STA $02
+	LDA.w #$F859 : STA $04
+	RTL
+.noSword
+	LDA SpecialBombs : AND.w #$00FF : BNE .bombSword
+	LDA.w #$0000 : STA $02
+	LDA.w #$F859 : STA $04
+	RTL
+.bombSword
+	LDA $7EF4A8 : AND.w #$00FF : STA $02
+	LDA.w #$FC51 : STA $04
+	RTL
+;--------------------------------------------------------------------------------

swordswap.asm

@@ -45,6 +45,7 @@ LookupDamageLevel:
 		LDA.l !StalfosBombDamage
 		RTL
 	+
+	LDA SpecialBombs : BNE .alt_table
 	PHP
 		REP #$20 ; set 16-bit accumulator
 		TXA : LSR : TAX : BCS .lower
@@ -58,6 +59,20 @@ RTL
 	LDA.l Damage_Table, X
 	AND.b #$0F
 RTL
+.alt_table
+	PHP
+		REP #$20 ; set 16-bit accumulator
+		TXA : LSR : TAX : BCS .alt_lower
+.alt_upper
+	PLP
+	LDA.l Damage_Table_Alt, X
+	LSR #4
+RTL
+.alt_lower
+	PLP
+	LDA.l Damage_Table_Alt, X
+	AND.b #$0F
+RTL
 ;================================================================================
 ; $7F50C0 - Sword Modifier
 LoadModifiedSwordLevel: ; returns short

tables.asm

@@ -98,7 +98,11 @@ db #$02 ; #$02 = Tempered Sword (default)
 ;org $05EBD4 ; PC 0x2EBD4 - sprite_zelda.asm:23 - (LDA $7EF359 : CMP.b #$02 : BCS .hasMasterSword) - Zelda Spawnpoint Sword Check
 ;db #$05 ; #$02 = Tempered Sword (default) - #$05 = All Swords
 ;--------------------------------------------------------------------------------
-; 0x18002B- 0x18002F (Unused)
+; 0x18002B- 0x18002E (Unused)
+;--------------------------------------------------------------------------------
+org $30802F ; PC 0x18003F
+SpecialBombs:
+db #$00 ; #$00 = Off (default) - #$01 = On
 ;--------------------------------------------------------------------------------
 org $308030 ; PC 0x180030
 EnableSRAMTrace:
@@ -223,10 +227,13 @@ db #$00 ; #$00 = Off (default) - #$01 = On (frog/smith can enter multi-entrance
 org $30804D ; PC 0x18004D
 EscapeAssist: ; ScrubMode:
 db #$00
-;---- -mba
+;-MBA -mba
-;m - Infinite Magic
+;M - Infinite Magic (after escape)
-;b - Infinite Bombs
+;B - Infinite Bombs (after escape)
-;a - Infinite Arrows
+;A - Infinite Arrows (after escape)
+;m - Infinite Magic (during escape)
+;b - Infinite Bombs (during escape)
+;a - Infinite Arrows (during escape)
 ;--------------------------------------------------------------------------------
 org $30804E ; PC 0x18004E
 UncleRefill:
@@ -1377,6 +1384,13 @@ db $04
 ;AD - Small Key of Ganon's Tower
 ;AE - Reserved
 ;AF - Generic Small Key
+
+;B0 - reserved for bee traps
+;B1 - L-2 Bombs
+;B2 - L-3 Bombs
+;B3 - L-4 Bombs
+;B4 - L-5 Bombs
+;B5 - Progressive Bombs
 ;================================================================================
 ;;Residual Portal
 ;org $0283E0 ; PC 0x103E0 (Bank02.asm:816) (BNE)

utilities.asm

@@ -160,8 +160,11 @@ RTL
 	;Ax
 	db $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F, $0F ; Free Small Key
 
+	;Bx
 	db $2C ; Bee Trap
-	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
+	db $13, $13, $13, $13, $13 ; Bomb Upgrades
+
+	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
 	db $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49, $49 ; Unused
@@ -196,7 +199,7 @@ GetSpritePalette:
 	;--------
 	TAX : LDA.l .gfxPalettes, X ; look up item gfx
 	PLB : PLX
-	CMP.b #$F8 : !BGE .specialHandling
+	CMP.b #$F7 : !BGE .specialHandling
 RTL
 	.specialHandling
 	CMP.b #$FD : BNE ++ ; Progressive Sword
@@ -290,7 +293,8 @@ RTL
 	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Free Big Key
 	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Free Small Key
 	db $04 ; Bee Trap
-	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Unused
+	db $0A, $0A, $0A, $0A, $0A; Bomb Upgrades
+	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Unused
 	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Unused
 	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Unused
 	db $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08 ; Unused

zelda.asm

@@ -10,7 +10,15 @@ SpawnZelda:
 ;--------------------------------------------------------------------------------
 EndRainState:
 	LDA $7EF3C5 : CMP.b #$02 : !BGE + ; skip if past escape already
-		LDA.b #$00 : STA !INFINITE_ARROWS : STA !INFINITE_BOMBS : STA !INFINITE_MAGIC
+		LDA.l EscapeAssist : AND #$44
+		CMP #$04 : BNE + : LDA #$00 : STA !INFINITE_MAGIC : +
+		CMP #$40 : BNE + : STA !INFINITE_MAGIC : +
+		LDA.l EscapeAssist : AND #$22
+		CMP #$02 : BNE + : LDA #$00 : STA !INFINITE_BOMBS : +
+		CMP #$20 : BNE + : STA !INFINITE_BOMBS : +
+		LDA.l EscapeAssist : AND #$11
+		CMP #$01 : BNE + : LDA #$00 : STA !INFINITE_ARROWS : +
+		CMP #$10 : BNE + : STA !INFINITE_ARROWS : +
 		LDA.b #$02 : STA $7EF3C5 ; end rain state
 		JSL MaybeSetPostAgaWorldState
 	+