43f753b517
Value defines styled without quotes, # moved to load/store/cmp site Added registers.asm (copied from spannerisms JP disassembly) Added a bunch of length annotations Deleted old or trivial commented out code Deleted: ganonfixes.asm, map.asm, seedtag.asm Replaced obsolete credits.asm with creditsnew.asm Moved scratch space at $7F5020-3F to mirrored WRAM (7E1E70-8F) Moved clock RAM to mirrored WRAM (7E1E90-9F) dialog.asm: FreeDungeonItemNotice preserves callee-preserved scratch RAM Toast buffer moved to mirrored WRAM (7E1E0E-0F) servicerequest.asm: long store to $012E converted to word length store
77 lines
2.7 KiB
NASM
77 lines
2.7 KiB
NASM
;================================================================================
|
|
; Boots State Modifier
|
|
;--------------------------------------------------------------------------------
|
|
ModifyBoots:
|
|
PHA
|
|
LDA.l BootsModifier : CMP.b #$01 : BNE +
|
|
PLA : AND.l AbilityFlags : ORA.b #$04 : RTL ; yes boots
|
|
+ : CMP.b #$02 : BNE +
|
|
PLA : AND.l AbilityFlags : AND.b #$FB : RTL ; no boots
|
|
+ : LDA.l FakeBoots : CMP.b #$01 : BNE +
|
|
LDA.b $5B : BEQ ++ : LDA.b $59 : BNE + ; hover check
|
|
++ : PLA : AND.l AbilityFlags : ORA.b #$04 : RTL ; yes boots, not hovering
|
|
+
|
|
PLA
|
|
AND.l AbilityFlags ; regular boots
|
|
RTL
|
|
;--------------------------------------------------------------------------------
|
|
AddBonkTremors:
|
|
PHA
|
|
LDA.b $46 : BNE + ; Check for incapacitated Link
|
|
JSL.l IncrementBonkCounter
|
|
+
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BNE + ; Check for Boots
|
|
PLA : RTL
|
|
+
|
|
PLA
|
|
JSL.l AddDashTremor : JSL.l Player_ApplyRumbleToSprites ; things we wrote over
|
|
RTL
|
|
;--------------------------------------------------------------------------------
|
|
BonkBreakableWall:
|
|
PHX : PHP
|
|
SEP #$30 ; set 8-bit accumulator and index registers
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BNE + ; Check for Boots
|
|
PLP : PLX : LDA.w #$0000 : RTL
|
|
+
|
|
PLP : PLX
|
|
LDA.w $0372 : AND.w #$00FF ; things we wrote over
|
|
RTL
|
|
;--------------------------------------------------------------------------------
|
|
BonkRockPile:
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BNE + ; Check for Boots
|
|
LDA.b #$00 : RTL
|
|
+
|
|
LDA.w $02EF : AND.b #$70 ; things we wrote over
|
|
RTL
|
|
;--------------------------------------------------------------------------------
|
|
GravestoneHook:
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BEQ .done ; Check for Boots
|
|
+
|
|
LDA.w $0372 : BEQ .done ; things we wrote over
|
|
JML.l moveGravestone
|
|
.done
|
|
JML.l GravestoneHook_continue
|
|
;--------------------------------------------------------------------------------
|
|
JumpDownLedge:
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BNE + ; Check for Boots
|
|
; Disarm Waterwalk
|
|
LDA.b $5B : CMP.b #$01 : BNE +
|
|
STZ.b $5B
|
|
+
|
|
LDA.b $1B : BNE .done : LDA.b #$02 : STA.b $EE ; things we wrote over
|
|
.done
|
|
RTL
|
|
;--------------------------------------------------------------------------------
|
|
BonkRecoil:
|
|
LDA.l BootsModifier : CMP.b #$01 : BEQ +
|
|
LDA.l BootsEquipment : BNE + ; Check for Boots
|
|
LDA.b #$16 : STA.b $29 : RTL
|
|
+
|
|
LDA.b #$24 : STA.b $29 ; things we wrote over
|
|
RTL
|